SWF帧频（FPS）对Socket连接的影响

2011-02-24 [1270] technology flashplayer sleepmode socket flash

SWF帧频（FPS）对Socket连接的影响

SWF帧频（FPS）对Socket连接的影响

Adobe官方帮助中对于Flash Player的睡眠模式有 这样一段介绍 ：

ActionScript 代码在睡眠模式下继续执行，这与将 Stage.frameRate 属性设置为 4 fps 类似。但是跳过呈现步骤，因此用户看不到该 Player 正在以 4 fps 的速率运行。之所以将帧速率选择为 4 fps （而不是 0），是因为该速率允许所有连接保持打开状态（NetStream、Socket 和 NetConnection）。将帧速率切换到 0 fps 会断开打开的连接。之所以将刷新速率选择为 250 毫秒 (4 fps)，是因为……。

确实是这样么？当FPS低于4或者为0的时候，Socket连接会断开么？低帧频的时候，通过Socket发送的数据，是根据帧率触发，还是直接触发呢？于是我写了个测试程序做了如下测试：

  • 在舞台上双击的时候，可以在帧频2和帧频0之间切换；
  • 每次EnterFrame的时候，向Socket服务器发送布尔值false；
  • 每次单击鼠标的时候，向Socket服务器发送布尔值true；
  • 在服务端，显示出每次发送数据之间的间隔，同时显示发送的数据内容（1=true，0=false）。

结论

  1. 将SWF帧频设为0的时候，Sokcet不会断开连接（等了十几分钟也没断开）；
  2. Socket的发送请求，与帧率是没有关系的，只要发送了，就会立即执行；
  3. 我每秒钟可以单击鼠标7次（这个很强悍！ :lol:）

服务器端的输出

//冒号前面是客户端传送的值，后面是时间间隔（毫秒）

connected 0:15.625 0:406.25 0:484.375 0:500 0:500 0:500 0:500 0:500 0:500 0:500 0:500 0:500 0:500 1:125 0:156.25 1:6796.875 0:93187.5 1:22328.125 0:125 0:500 0:484.375 0:500 0:484.375 0:515.625 0:500 0:484.375 0:515.625 1:218.75 0:203.125

代码

 1package
 2{
 3import flash.display.Sprite;
 4import flash.events.ErrorEvent;
 5import flash.events.Event;
 6import flash.events.IOErrorEvent;
 7import flash.events.MouseEvent;
 8import flash.events.SecurityErrorEvent;
 9import flash.net.Socket;
10
11[SWF(width=300,height=200,frameRate=2)]
12public class SocketFPSTest extends Sprite
13{
14	public function SocketFPSTest()
15	{
16		_socket = new Socket();
17		_socket.addEventListener(Event.CONNECT, handler_connect);
18		_socket.addEventListener(IOErrorEvent.IO_ERROR, handler_error);
19		_socket.addEventListener(SecurityErrorEvent.SECURITY_ERROR, handler_error);
20		this.stage.doubleClickEnabled = true;
21		this.stage.addEventListener(MouseEvent.CLICK, handler_click);
22		this.stage.addEventListener(MouseEvent.DOUBLE_CLICK, handler_doubleClick);
23		this.stage.addEventListener(Event.ENTER_FRAME, handler_enterFrame);
24		trace('frameRate:', this.stage.frameRate);
25	}
26
27	private var _socket:Socket;
28
29	private function handler_error(evt:ErrorEvent):void
30	{
31		trace(evt.toString());
32	}
33
34	private function handler_connect(evt:Event):void
35	{
36		trace('连接成功！');
37	}
38
39	//每500毫秒自动发送一次消息，传送false
40	private function handler_enterFrame(evt:Event):void
41	{
42		send(false);
43		trace('enterFrame send');
44	}
45
46	//双击切换帧频
47	private function handler_doubleClick(evt:MouseEvent):void
48	{
49		this.stage.frameRate = (this.stage.frameRate==2) ? 0 : 2;
50	}
51
52	//单击鼠标的时候发送一次消息，传送true
53	private function handler_click(evt:MouseEvent):void
54	{
55		send(true);
56
57	}
58
59	private function send($value:Boolean):void
60	{
61		if(!_socket.connected)
62			_socket.connect('127.0.0.1', 3000);
63		else
64		{
65			_socket.writeBoolean($value);
66			_socket.flush();
67		}
68	}
69}
70}